【魔法飞弹】（函数+截图）感谢原提供者Westwood

eff · 发表于 2009-7-5 21:16:16

[jass]
    constant real               SYD_PI=3.14159
    constant real               SYD_PI2=1.570795
    constant real               SYD_TODEG=180/3.14159
    constant real               SYD_TORAD=3.14159/180

function MissileWithTargetGroup takes nothing returns nothing
    local unit u = GetEnumUnit()
    local integer vMix = GetUnitUserData(u)
    local integer aParam = Modi(vMix,200)
    local integer rParam = Modi_EX(vMix,120000,200)
    local integer tParam = vMix/120000
    local integer vLimit = SYS_GroupTempData[1]
    local integer cur = tParam - SYS_GroupTempData[0]
    local real bAngle
    local real bAngleEx
    local real r
    local real d
    local real x
    local real y
    set SYS_GroupInt = SYS_GroupInt + 1
    if(cur<=0)then
    elseif(cur>0 and cur<vLimit)then
        set bAngle = cur*SYD_PI/vLimit
        set r=1-Cos(bAngle)
        set d=r*Sin(bAngle)*rParam
        set r=r*Cos(bAngle)*SYS_GroupTempDataR[0]
        set bAngleEx = I2R(aParam)*SYD_TORAD
        call SetUnitFlyHeight(u,60+d*Sin(bAngleEx),0)
        set x = GetUnitX(SYS_GroupUnit)+r*Cos(SYS_GroupTempDataR[1])+d*Cos(bAngleEx)*Cos(SYS_GroupTempDataR[2])
        set y = GetUnitY(SYS_GroupUnit)+r*Sin(SYS_GroupTempDataR[1])+d*Cos(bAngleEx)*Sin(SYS_GroupTempDataR[2])
        call SetUnitX(u,x)
        call SetUnitY(u,y)
    elseif(cur>=vLimit)then
        call RemoveUnit(u)
        call GroupRemoveUnit(SYS_Group,u)
        set SYS_GroupInt = SYS_GroupInt - 1
    endif
    set u = null
endfunction

function MissileWithTargetLoop takes nothing returns nothing
    local integer tmIndex = GetTimerIndex(GetExpiredTimer())
    local unit su = SYS_TimerData_U00[tmIndex]
    local unit tu = SYS_TimerData_U01[tmIndex]
    set SYS_Group = SYS_TimerData_Group[tmIndex]
    set SYS_GroupUnit = su
    set SYS_GroupTarget = tu
    set SYS_GroupInt = 0
    set SYS_GroupTempData[0] = SYS_TimerData_I00[tmIndex]
    set SYS_GroupTempData[1] = SYS_TimerData_I01[tmIndex]
    set SYS_GroupTempDataR[0] = iGetDistanceBetweenUnit(su,tu)/2
    set SYS_GroupTempDataR[1] = iGetAngleBetweenUnit(su,tu)
    set SYS_GroupTempDataR[2] = iGetAngleBetweenUnit(su,tu) - SYD_PI2
    call ForGroup(SYS_Group,function MissileWithTargetGroup)
    if(SYS_GroupInt<=0)then
        call DestroyGroup(SYS_Group)
        set SYS_Group = null
        set SYS_GroupUnit = null
        set SYS_GroupTarget = null
        call ReleaseTimer(GetExpiredTimer())
    else
        set SYS_TimerData_I00[tmIndex] = SYS_TimerData_I00[tmIndex] - 1
    endif
set su = null
set tu = null
endfunction

function MissileWithTargetLanch takes unit su,unit tu,integer Num,integer aMin,integer aMax,integer dMax,integer rLatency,integer bIndex returns nothing
    local integer tmIndex
    local integer i = Num
    local integer vMix
    local integer rParam
    local integer aParam
    local integer tParam
    local integer vLimit = IConfig(R2I(iGetDistanceBetweenUnit(su,tu)/6.0),40,80)
    local group gp
    local unit blot
    local integer blotId = 'u00A'
    local real uFacing = GetUnitFacing(su)
    local location loc
    if(i<=0)then
        return
    endif
    set loc = GetUnitLoc(su)
    set tmIndex = GetTimerIndex(GetTimer())
    set gp = CreateGroup()
    loop
        exitwhen(i<=0)
        set aParam = IConfig(GetRandomInt(aMin,aMax),-90,90)+90
        set rParam = GetRandomInt(0,IConfig(dMax,0,512))
        set tParam = GetRandomInt(80,80+IConfig(rLatency,0,40))
        set vMix = tParam*120000 + rParam*200 + aParam
        set blot = CreateUnit(GetOwningPlayer(su),blotId,GetUnitX(su),GetUnitY(su),uFacing+aParam)
        call SetUnitFlyHeight(blot,60+GetLocationZ(loc),0)
        call SetUnitIgnoreRegister(blot)
        call SetUnitUserData(blot,vMix)
        call GroupAddUnit(gp,blot)
        set i = i - 1
    endloop
    set SYS_TimerData_U00[tmIndex] = su
    set SYS_TimerData_U01[tmIndex] = tu
    set SYS_TimerData_I00[tmIndex] = vLimit + rLatency
    set SYS_TimerData_I01[tmIndex] = vLimit
    set SYS_TimerData_I02[tmIndex] = bIndex
    set SYS_TimerData_Group[tmIndex] = gp
    call TimerStart(SYS_Timer[tmIndex],0.025,true,function MissileWithTargetLoop)
    call RemoveLocation(loc)
    set gp = null
    set blot = null
    set loc = null
endfunction
[/jass]

eff · 发表于 2009-7-5 21:17:07

。。貌似发错地方了。。谁帮我挪到jass区。。

eff · 发表于 2009-7-6 08:58:22

恩。此函数使用单位传递数据，方便修改

westwood · 发表于 2009-7-6 11:28:24

把目标距离放远点比较cool些，你这个截图不太能显示出来~

还是施放时即创造所有bolt而不是在delay到期时么

eff · 发表于 2009-7-6 11:53:41

因为是用单位传递数据的。。

话说不看懂你这函数什么意思还真没法改

nikki · 发表于 2009-7-6 17:09:31

帅死了

jpg · 发表于 2009-7-6 18:22:11

还好玩.

westwood · 发表于 2009-7-6 18:24:46

引用第4楼eff于2009-07-06 11:53发表的 :
因为是用单位传递数据的。。

话说不看懂你这函数什么意思还真没法改

你可以先全部创建然后隐藏呵，到点再show

函数核心部分是纯数学…

我这个是定时间抵达的，所以距离近时感觉较慢
需要弄成按距离么？

死海文书 · 发表于 2009-7-7 04:00:22

这应该叫可变弧度弹道=v= 曾经用T做这个因为太麻烦么耐心就放弃了...还是JASS方便函数偶收下了

westwood · 发表于 2009-7-7 10:45:47

这个每个飞弹是厚薄不同的心形曲线，不是普通弧线（图片里看不太出来，放远了比较明显）

eff · 发表于 2009-7-7 11:49:31

另外提一点
IConfig(val,min,max)会返回val介于max和min之间的一个值

死海文书 · 发表于 2009-7-7 13:13:52

=v= 安啦安啦偶看出来了
明白是什么意思

巧樂滋聖代 · 发表于 2009-7-7 16:21:21

不错的曲线公式、、hmmm、、

alexries · 发表于 2009-7-9 16:58:02

是的，非常美丽。

alexries · 发表于 2009-7-9 16:58:44

手痒忍不住点了致谢。

gducn · 发表于 2009-7-9 19:07:01

第二个函数有两个单位变量泄露,技能SET NULL 一下

wcl920603 · 发表于 2009-7-9 21:58:11

太漂亮了，多谢提供！！！！

eff · 发表于 2009-7-10 08:46:59

哦对，忘记了泄漏。
以补上

剑魔 · 发表于 2009-7-13 17:20:10

支持了。。算法盲路过。。。

gallon · 发表于 2009-7-14 17:55:42

我完全不懂的JASS……
效果很好很强大~~

		自动登录	找回密码
密码			点一下

【魔法飞弹】（函数+截图）感谢原提供者Westwood

评分